Re: OBJECTS.FS Question

ragofu64@[EMAIL PROTECTED]
 wrote:
> I finally made it work.  I attach the source code.

That's great.  Thank you.

The syntax still seems like a lot of work compared to other objects 
packages.  Consider the same example in Neon.  No need for the following 
words:

interface
selector
end-interface
persistant
implementation
inst-var
methods
overrides
end-methods
dict-new
constant

The default early binding will cause 'print: p1' to execute about twice 
as fast as the objects.fs 'p1 print'.  Forcing Neon to late bind with 
'p1 print: **' will give about the same execution speed.  As it always 
has been, Neon is compatible with image saving and turnkeys.

-Doug

:class per1
    var m-count

:m classinit: 0 put: m-count ;m

:m print:
	." count is " print: m-count cr
	1 +: m-count ;m

:m foo:
	." I'm foo selector" cr ;m
	
:m bar:
	." I'm bar method" ;m

:m sel4:
	." I'm selector sel4" cr ;m

;class


per1 p1

\ early binding
print: p1
print: p1

\ or late binding
p1 print: **
p1 print: **



> 0 [if] \ example code
> 
> interface
>    selector sel1
>    selector sel2
> end-interface i-test1 persistant
> 
> interface
>    selector sel3
>    selector sel4
> end-interface i-test2 persistant
> 
> object class
>    i-test2 implementation
> 
>    Cell% inst-var m-count
> 
>    selector foo
> 
> end-class per1
> 
> per1 methods
> public
> 
>   m:
>      m-count off
>   ;m  overrides construct
> 
>   m:
>      ." count is " m-count ? cr
>      1 m-count +!
>   ;m  overrides print
> 
>   m:
>      ." I'm foo selector" cr
>   ;m overrides foo
> 
>   :m bar
>      ." I'm bar method"
>   ;m
> 
>   m:
>      ." I'm selector sel4" cr
>   ;m overrides sel4
> 
> end-methods persistant
> 
> per1 dict-new constant p1
> 
> p1 print
> p1 print
> 
> save persis.elf cr
> bye